rts/CMakeLists.txt

cmake_minimum_required(VERSION 3.13)

option(PS1_BUILD "Build for the original Sony Playstation" OFF)
option(HOST_BUILD "Build for host platform using SDL-1.2" OFF)
option(WIN9X_BUILD "Build for Win9x using SDL-1.2" OFF)

if(NOT PS1_BUILD AND NOT HOST_BUILD AND NOT WIN9X_BUILD)
    message(FATAL_ERROR "Please define target platform. Available options:
        PS1_BUILD
        HOST_BUILD
        WIN9X_BUILD
        Run CMake again using one of the available platforms e.g.: cmake .. -DPS1_BUILD=1")
endif()

if(PS1_BUILD)
    include("cmake/ps1-toolchain.cmake")
elseif(WIN9X_BUILD)
    include("cmake/win9x-toolchain.cmake")
endif()

project(rts)

add_executable(${PROJECT_NAME} "src/main.c")
set(cdroot ${CMAKE_BINARY_DIR}/cdimg)
# Avoid C11 since it is not supported by the i386-mingw32 toolchain.
set(cflags -Wall -g3 -ffunction-sections -fdata-sections -pedantic -std=c99)

if(PS1_BUILD)
    include("cmake/ps1.cmake")
elseif(WIN9X_BUILD)
    include("cmake/win9x.cmake")
elseif(HOST_BUILD)
    include("cmake/host.cmake")
endif()

add_subdirectory("res")

set(components
    building
    camera
    container
    font
    game
    gfx
    gui
    header
    instance
    keyboard
    mouse
    pad
    player
    resource
    sfx
    system
    terrain
    unit
    util
)

set(interfaces
    tech
)

target_compile_options(${PROJECT_NAME} PUBLIC ${cflags})

foreach(c ${components})
    add_subdirectory("src/${c}")
    target_compile_options(${c} PUBLIC ${cflags})
    target_link_libraries(${PROJECT_NAME} PRIVATE ${c})
endforeach()

foreach(i ${interfaces})
    add_subdirectory("src/${i}")
    target_compile_options(${i} INTERFACE ${cflags})
    target_link_libraries(${PROJECT_NAME} PRIVATE ${c})
endforeach()

target_link_options(${PROJECT_NAME} PRIVATE -Wl,--gc-sections)