1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
|
/*-------------------------------------------------------------------------
_modulong.c - routine for modulus of 32 bit unsigned long
Copyright (C) 1999, Sandeep Dutta . sandeep.dutta@usa.net
Bug fixes by Martijn van Balen, aed@iae.nl
This library is free software; you can redistribute it and/or modify it
under the terms of the GNU General Public License as published by the
Free Software Foundation; either version 2, or (at your option) any
later version.
This library is distributed in the hope that it will be useful,
but WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
GNU General Public License for more details.
You should have received a copy of the GNU General Public License
along with this library; see the file COPYING. If not, write to the
Free Software Foundation, 51 Franklin Street, Fifth Floor, Boston,
MA 02110-1301, USA.
As a special exception, if you link this library with other files,
some of which are compiled with SDCC, to produce an executable,
this library does not by itself cause the resulting executable to
be covered by the GNU General Public License. This exception does
not however invalidate any other reasons why the executable file
might be covered by the GNU General Public License.
-------------------------------------------------------------------------*/
/* Assembler-functions are provided for:
mcs51 small
mcs51 small stack-auto
*/
#if !defined(__SDCC_USE_XSTACK) && !defined(_SDCC_NO_ASM_LIB_FUNCS)
# if defined(__SDCC_mcs51)
# if defined(__SDCC_MODEL_SMALL)
# if defined(__SDCC_STACK_AUTO) && !defined (__SDCC_PARMS_IN_BANK1)
# define _MODULONG_ASM_SMALL_AUTO
# else
# define _MODULONG_ASM_SMALL
# endif
# endif
# endif
#endif
#if defined _MODULONG_ASM_SMALL
static void
_modlong_dummy (void) __naked
{
__asm
.globl __modulong
#define a0 dpl
#define a1 dph
#define a2 b
#define a3 r1
#define count r0
__modulong:
#if defined(__SDCC_PARMS_IN_BANK1)
#define b0 (b1_0)
#define b1 (b1_1)
#define b2 (b1_2)
#define b3 (b1_3)
#else
#if defined(__SDCC_NOOVERLAY)
.area DSEG (DATA)
#else
.area OSEG (OVR,DATA)
#endif
.globl __modulong_PARM_2
.globl __modslong_PARM_2
__modulong_PARM_2:
__modslong_PARM_2:
.ds 4
.area CSEG (CODE)
#define b0 (__modulong_PARM_2)
#define b1 (__modulong_PARM_2 + 1)
#define b2 (__modulong_PARM_2 + 2)
#define b3 (__modulong_PARM_2 + 3)
#endif
; parameter a comes in a, b, dph, dpl
mov a3,a ; save parameter a3
mov a,b0 ; b == 0? avoid endless loop
orl a,b1
orl a,b2
orl a,b3
jz div_by_0
mov count,#0
clr c ; when loop1 jumps immediately to loop2
loop1: inc count
mov a,b3 ; if (!MSB_SET(b))
jb acc.7,loop2
mov a,b0 ; b <<= 1
add a,acc
mov b0,a
mov a,b1
rlc a
mov b1,a
mov a,b2
rlc a
mov b2,a
mov a,b3
rlc a
mov b3,a
mov a,a0 ; a - b
subb a,b0 ; here carry is always clear
mov a,a1
subb a,b1
mov a,a2
subb a,b2
mov a,a3
subb a,b3
jnc loop1
clr c
mov a,b3 ; b >>= 1;
rrc a
mov b3,a
mov a,b2
rrc a
mov b2,a
mov a,b1
rrc a
mov b1,a
mov a,b0
rrc a
mov b0,a
loop2: ; clr c never set
mov a,a0 ; a - b
subb a,b0
mov r4,a
mov a,a1
subb a,b1
mov r5,a
mov a,a2
subb a,b2
mov r6,a
mov a,a3
subb a,b3
jc smaller ; a >= b?
mov a3,a ; -> yes; a = a - b;
mov a2,r6
mov a1,r5
mov a0,r4
smaller: ; -> no
clr c
mov a,b3 ; b >>= 1;
rrc a
mov b3,a
mov a,b2
rrc a
mov b2,a
mov a,b1
rrc a
mov b1,a
mov a,b0
rrc a
mov b0,a
djnz count,loop2
mov a,a3 ; prepare the return value
div_by_0:
ret
__endasm;
}
#elif defined _MODULONG_ASM_SMALL_AUTO
static void
_modlong_dummy (void) __naked
{
__asm
.globl __modulong
__modulong:
#define count r0
#define a0 dpl
#define a1 dph
#define a2 b
#define a3 r1
#define b0 r2
#define b1 r3
#define b2 r4
#define b3 r5
ar2 = 2 ; BUG register set is not considered
ar3 = 3
ar4 = 4
ar5 = 5
.globl __modlong ; entry point for __modslong
; parameter a comes in a, b, dph, dpl
mov a3,a ; save parameter a3
mov a,sp
add a,#-2-3 ; 2 bytes return address, 3 bytes param b
mov r0,a ; r1 points to b0
mov ar2,@r0 ; load b0
inc r0 ; r0 points to b1
mov ar3,@r0 ; b1
inc r0
mov ar4,@r0 ; b2
inc r0
mov ar5,@r0 ; b3
__modlong: ; entry point for __modslong
; a in r1, b, dph, dpl
; b in r5, r4, r3, r2
mov count,#0
mov a,b0 ; b == 0? avoid endless loop
orl a,b1
orl a,b2
orl a,b3
jz div_by_0
mov count,#0
clr c ; when loop1 jumps immediately to loop2
loop1: inc count
mov a,b3 ; if (!MSB_SET(b))
jb acc.7,loop2
mov a,b0 ; b <<= 1
add a,acc
mov b0,a
mov a,b1
rlc a
mov b1,a
mov a,b2
rlc a
mov b2,a
mov a,b3
rlc a
mov b3,a
mov a,a0 ; a - b
subb a,b0 ; here carry is always clear
mov a,a1
subb a,b1
mov a,a2
subb a,b2
mov a,a3
subb a,b3
jnc loop1
clr c
mov a,b3 ; b >>= 1;
rrc a
mov b3,a
mov a,b2
rrc a
mov b2,a
mov a,b1
rrc a
mov b1,a
mov a,b0
rrc a
mov b0,a
loop2: ; clr c never set
mov a,a0 ; a - b
subb a,b0
mov a,a1
subb a,b1
mov r6,a ; d1
mov a,a2
subb a,b2
mov r7,a ; d2
mov a,a3
subb a,b3
jc smaller ; a >= b?
mov a3,a ; -> yes; a = a - b;
mov a2,r7
mov a1,r6
mov a,a0
subb a,b0
mov a0,a
smaller: ; -> no
clr c
mov a,b3 ; b >>= 1;
rrc a
mov b3,a
mov a,b2
rrc a
mov b2,a
mov a,b1
rrc a
mov b1,a
mov a,b0
rrc a
mov b0,a
djnz count,loop2
mov a,a3 ; prepare the return value
div_by_0:
ret
__endasm;
}
#else // _MODULONG_ASM
#define MSB_SET(x) ((x >> (8*sizeof(x)-1)) & 1)
unsigned long
_modulong (unsigned long a, unsigned long b)
{
unsigned char count = 0;
while (!MSB_SET(b))
{
b <<= 1;
if (b > a)
{
b >>=1;
break;
}
count++;
}
do
{
if (a >= b)
a -= b;
b >>= 1;
}
while (count--);
return a;
}
#endif // _MODULONG_ASM
|
