blob: c22bbb3e7d87c72a526690eee1c094b745cc4df8 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
|
include(../qxmpp.pri)
QT -= gui
TEMPLATE = lib
CONFIG += $$QXMPP_LIBRARY_TYPE
DEFINES += QXMPP_BUILD
DEFINES += $$QXMPP_INTERNAL_DEFINES
INCLUDEPATH += $$QXMPP_INCLUDEPATH $$QXMPP_INTERNAL_INCLUDES
LIBS += $$QXMPP_INTERNAL_LIBS
# To enable support for the Speex audio codec, pass QXMPP_USE_SPEEX=1 to qmake.
!isEmpty(QXMPP_USE_SPEEX) {
DEFINES += QXMPP_USE_SPEEX
LIBS += -lspeex
}
# To enable support for the Theora video codec, pass QXMPP_USE_THEORA=1 to qmake.
!isEmpty(QXMPP_USE_THEORA) {
DEFINES += QXMPP_USE_THEORA
LIBS += -ltheoradec -ltheoraenc
}
# To enable support for the Vpx video codec, pass QXMPP_USE_VPX=1 to qmake.
!isEmpty(QXMPP_USE_VPX) {
DEFINES += QXMPP_USE_VPX
LIBS += -lvpx
}
# Target definition
TARGET = $$QXMPP_LIBRARY_NAME
VERSION = $$QXMPP_VERSION
win32 {
DESTDIR = $$OUT_PWD
}
include(base/base.pri)
include(client/client.pri)
include(server/server.pri)
HEADERS += $$INSTALL_HEADERS
# Installation
headers.files = $$INSTALL_HEADERS
headers.path = $$PREFIX/include/qxmpp
target.path = $$PREFIX/$$LIBDIR
INSTALLS += headers target
# pkg-config support
CONFIG += create_pc create_prl no_install_prl
QMAKE_PKGCONFIG_DESTDIR = pkgconfig
QMAKE_PKGCONFIG_LIBDIR = $$target.path
QMAKE_PKGCONFIG_INCDIR = $$headers.path
|
