QXmppConfig.cmake.in


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32

# SPDX-FileCopyrightText: 2017 Niels Ole Salscheider <niels_ole@salscheider-online.de>
#
# SPDX-License-Identifier: CC0-1.0

@PACKAGE_INIT@

set(_QXmpp_FIND_PARTS_REQUIRED)
if(QXmppQt@QT_VERSION_MAJOR@_FIND_REQUIRED)
    set(_QXmpp_FIND_PARTS_REQUIRED REQUIRED)
endif()
set(_QXmpp_FIND_PARTS_QUIET)
if(QXmppQt@QT_VERSION_MAJOR@_FIND_QUIETLY)
    set(_QXmpp_FIND_PARTS_QUIET QUIET)
endif()

include(CMakeFindDependencyMacro)
find_dependency(Qt@QT_VERSION_MAJOR@Core)
find_dependency(Qt@QT_VERSION_MAJOR@Network)
find_dependency(Qt@QT_VERSION_MAJOR@Xml)

include("${CMAKE_CURRENT_LIST_DIR}/QXmpp.cmake")

foreach(module ${QXmppQt@QT_VERSION_MAJOR@_FIND_COMPONENTS})
    find_package(QXmpp${module}Qt@QT_VERSION_MAJOR@
        ${QXmppQt@QT_VERSION_MAJOR@_FIND_VERSION}
        ${_QXmpp_FIND_PARTS_REQUIRED}
        ${_QXmpp_FIND_PARTS_QUIET}
    )
    set(QXmppQt@QT_VERSION_MAJOR@_${module}_FOUND ${QXmpp${module}Qt@QT_VERSION_MAJOR@_FOUND})
endforeach()

check_required_components(QXmpp)