doc/gem-to-man.awk


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83

#!/usr/bin/env -S awk -f

BEGIN {
    preformatted=0
}

# Empty lines
/^$/ {
    print "."
    next
}

# Level 2 headings become section headings.
/^##\s/ {
    print ".SH"
    sub(/^##\s/, "")
    print toupper($0)
    next
}

# Level 3 headings become subsection headings.
/^###\s/ {
    sub(/^###\s/, "")
    print ".SS \"" $0 "\""
    next
}

# Lists
/^\*\s/ {
    print ".IP \\(bu 3"
    sub(/^\*\s/, "")
    print
    next
}

# Preformatted text
/^```/ {
    # We simply place indent macros to make
    # it stand out a little.
    if (!preformatted)
    {
        print ".RS"
        preformatted=1
    }
    else
    {
        preformatted=0
        print ".RE"
    }
    next
}

# Links
/^=>/ {
    # Strips => prefix, and separates URL and link
    # title.
    sub(/^=>/, "")
    url=$1
    $1=""
    title=$0

    print ".IP"

    # Print either URL on its own or Title: URL if we
    # have a title.
    if (title == "")
    {
        print url
    }
    else
    {
        gsub(/^\s/, "", title)
        print title ": " url
    }

    next
}

# Paragraphs (default)
{
    print ".PP"
    print
}