1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
|
;
; Copyright (c) 2016-2019 Matt Borgerson
;
; Permission is hereby granted, free of charge, to any person obtaining a copy
; of this software and associated documentation files (the "Software"), to deal
; in the Software without restriction, including without limitation the rights
; to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
; copies of the Software, and to permit persons to whom the Software is
; furnished to do so, subject to the following conditions:
;
; The above copyright notice and this permission notice shall be included in
; all copies or substantial portions of the Software.
;
; THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
; IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
; FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
; AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
; LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
; OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
; SOFTWARE.
;
bits 32
%define NUM_HANDLERS 32
section .data
global dbg_int_handlers
; Generate table of handlers
dbg_int_handlers:
%macro handler_addr 1
dd dbg_int_handler_%1
%endmacro
%assign i 0
%rep NUM_HANDLERS
handler_addr i
%assign i i+1
%endrep
section .text
extern dbg_int_handler
%macro int 1
dbg_int_handler_%1:
push 0 ; Dummy Error code
push %1 ; Interrupt Vector
jmp dbg_int_handler_common
%endmacro
%macro inte 1
dbg_int_handler_%1:
; Error code already on stack
push %1 ; Interrupt Vector
jmp dbg_int_handler_common
%endmacro
; Generate Interrupt Handlers
%assign i 0
%rep NUM_HANDLERS
%if (i == 8) || ((i >= 10) && (i <= 14)) || (i == 17)
inte i
%else
int i
%endif
%assign i i+1
%endrep
; Common Interrupt Handler
dbg_int_handler_common:
pushad
push ds
push es
push fs
push gs
push ss
mov ebp, esp
; Stack:
; - EFLAGS
; - CS
; - EIP
; - ERROR CODE
; - VECTOR
; - EAX
; - ECX
; - EDX
; - EBX
; - ESP
; - EBP
; - ESI
; - EDI
; - DS
; - ES
; - FS
; - GS
; - SS
push ebp
call dbg_int_handler
mov esp, ebp
pop ss
pop gs
pop fs
pop es
pop ds
popad
add esp, 8 ; Pop error & vector
iret
|
